if targetexists "harmful"
  @canceltarget
  @cancelautotarget
endif
if not listexists 'BodyTypes'
  createlist 'BodyTypes'
  //dragon
  pushlist 'BodyTypes' 0x3b
  //human
  pushlist 'BodyTypes' 0x190
  pushlist 'BodyTypes' 0x191
  //wraith
  pushlist 'BodyTypes' 0x2ec
  pushlist 'BodyTypes' 0x2eb
  //elf
  pushlist 'BodyTypes' 0x25d
  pushlist 'BodyTypes' 0x25e
  //garg
  pushlist 'BodyTypes' 0x29a
  //lich
  // pushlist 'BodyTypes' 0x2ed
  //vamp
  // pushlist 'BodyTypes' 0x2e9
  // pushlist 'BodyTypes' 0x2e8
endif
//find lowest hp friend
clearignorelist
ignoreobject 'self'
@setalias 'buddy' 'self'
for 0 to 'BodyTypes'
  while @findtype BodyTypes[] 'any' ground 0 10
    if @infriendlist 'found' and hits 'found' < hits 'buddy'
      @setalias 'buddy' 'found'
    endif
    ignoreobject 'found'
  endwhile
endfor
if targetexists 'server' or targetexists 'beneficial'
  target! 'buddy'
endif
if @inrange 'buddy' 10
  if poisoned 'buddy' and not yellowhits 'buddy'
    cast 'cure' 'buddy'
  elseif hits 'buddy' < 99 and not yellowhits 'buddy'
    cast 'heal' 'buddy'
  elseif yellowhits 'buddy' and diffhits 'self' < 5
    cast "Cleansing Winds" 'buddy'
  endif
endif