vk1C::Send, {vk1C}
 
vk1C & a::toggleChange(toggle_a, "AHK") ; ☆
vk1C & e::toggleChange(toggle_e, "Edit")        ; ☆
 
;==============================
 
; toggleの真偽を反転
toggleChange(ByRef toggle, name)
{
        toggle := !toggle
        myToolTipFunction("カスタムモード(" . name . "): " . (toggle = true ? "ON" : "OFF"), 1000)
 
        CoordMode, ToolTip, Screen
        ToolTip, % (toggle = true ?  "カスタムモード(" . name . "): ON" : ""), 0, 0, 20
        CoordMode, ToolTip, Relative
}
 
; ツールチップ周りの処理を効率化
myToolTipFunction(str, delay)
{
        ToolTip, %str%
        SetTimer, RemoveToolTip, -%delay%
}
 
RemoveToolTip:
        ToolTip
Return
 
;==============================
 
; AutoHotkey///////////////////
#If, toggle_a = true
 
        ; AHKをリロード
        r::Reload
 
        ; AHKWiki(日本語)を開く
        h::
                Run, http://ahkwiki.net/Top
                toggleChange(toggle_a, "AHK")   ; ☆
        Return
   
#If
 
; Edit/////////////////////////
#If, toggle_e = true
 
        ; 1行削除
        e::
                Send, {End}+{Home}{Delete}
                toggleChange(toggle_e, "Edit")  ; ☆
        Return
       
        ; 1行挿入
        l::
                Send, {Home}{Enter}{Up}
                toggleChange(toggle_e, "Edit")  ; ☆
        Return
   
#If
;==============================