abstract class FabricNetwork {
contains Organization[1..*] organizations
contains Channel[1..*] channels
}
class RaftFabricNetwork extends FabricNetwork.
abstract class Node.
class Host {
contains Node[1..4] nodes
}
class ChaincodeInstance {
EndorsingNode[2..*] endorsedBy opposite endorses
}
class EndorsingNode extends Node {
ChaincodeInstance[1..*] endorses opposite endorsedBy
}
class Channel {
contains ChaincodeInstance[1..*] chaincodes
}
class Organization {
contains Host[1..*] hosts
}
pred collaboratesWith(Organization o1, Organization o2) <->
participatesIn(o1, commonChannel),
participatesIn(o2, commonChannel),
o1 != o2.
pred peers(Channel ch, Node n) <->
chaincodes(ch, code),
endorsedBy(code, n).
pred participatesIn(Organization org, Channel ch) <->
hosts(org, host),
nodes(host, node),
peers(ch, node).
RaftFabricNetwork(m_network).
Organization(m_org).
!exists(Organization::new).
Channel(ch1).
!exists(Channel::new).
Host(h1).
Host(h2).
!exists(Host::new).
EndorsingNode(node1).
EndorsingNode(node2).
!exists(EndorsingNode::new).
ChaincodeInstance(cc1).
ChaincodeInstance(cc2).
!exists(ChaincodeInstance::new).
organizations(m_network, m_org).
channels(m_network, ch1).
hosts(m_org, h1).
hosts(m_org, h2).
nodes(h1, node1).
nodes(h2, node2).
default !nodes(*, *).
scope FabricNetwork = 1.
{"html5":"htmlmixed","css":"css","javascript":"javascript","php":"php","python":"python","ruby":"ruby","lua":"text\/x-lua","bash":"text\/x-sh","go":"go","c":"text\/x-csrc","cpp":"text\/x-c++src","diff":"diff","latex":"stex","sql":"sql","xml":"xml","apl":"apl","asterisk":"asterisk","c_loadrunner":"text\/x-csrc","c_mac":"text\/x-csrc","coffeescript":"text\/x-coffeescript","csharp":"text\/x-csharp","d":"d","ecmascript":"javascript","erlang":"erlang","groovy":"text\/x-groovy","haskell":"text\/x-haskell","haxe":"text\/x-haxe","html4strict":"htmlmixed","java":"text\/x-java","java5":"text\/x-java","jquery":"javascript","mirc":"mirc","mysql":"sql","ocaml":"text\/x-ocaml","pascal":"text\/x-pascal","perl":"perl","perl6":"perl","plsql":"sql","properties":"text\/x-properties","q":"text\/x-q","scala":"scala","scheme":"text\/x-scheme","tcl":"text\/x-tcl","vb":"text\/x-vb","verilog":"text\/x-verilog","yaml":"text\/x-yaml","z80":"text\/x-z80"}